MFP

The place where you can meet MJJ members (French language)

Moderators: felx, Moderator Team

MFP

Postby herrv » Wed Jan 28, 2004 6:36 pm

Salut a tous
je ne trouve pas comment reinitialiser le mfp apres un reset
est ce que quelqu'un aurait de la doc ou une info a ce sujet
merci d'avence !
a+
HerrV
------------------------------------------------------
------------ /|\ l a p i n d e f /|\ -------------
* Pray The UnHoly Lapinou From Hell ! *
------------------------------------------------------
User avatar
herrv
Captain Atari
Captain Atari
 
Posts: 339
Joined: Thu May 29, 2003 10:19 am
Location: Rennes

Postby Shazz » Wed Jan 28, 2004 6:46 pm

regarde la dedans ca peut p-e aider...
You do not have the required permissions to view the files attached to this post.
...8bits are enough...
User avatar
Shazz
Atari Super Hero
Atari Super Hero
 
Posts: 548
Joined: Wed Aug 27, 2003 9:27 am
Location: Crétin des Alpes dauphinoises

Postby Zorro 2 » Thu Jan 29, 2004 9:11 am

As-tu fait un truc du style :
Code: Select all

...

init:
   MOVE.B   $FFFFFA07.W,MFP
   MOVE.B   $FFFFFA09.W,MFP+1
   MOVE.B   $FFFFFA0F.W,MFP+2
   MOVE.B   $FFFFFA13.W,MFP+3
   MOVE.B   $FFFFFA1B.W,MFP+4
   MOVE.B   $FFFFFA21.W,MFP+5
...
   clr.b   $fffffa07.w
   clr.b   $fffffa09.w
...
                rts
...

desinit:
   MOVE.B   MFP,$FFFFFA07.W
   MOVE.B   MFP+1,$FFFFFA09.W
   MOVE.B   MFP+2,$FFFFFA0F.W
   MOVE.B   MFP+3,$FFFFFA13.W
   MOVE.B   MFP+4,$FFFFFA1B.W
   MOVE.B   MFP+5,$FFFFFA21.W

...
                rts
...
   SECTION   BSS
MFP   DS.B   8
   DS.B   256
Member of NoExtra Team
User avatar
Zorro 2
Administrator
Administrator
 
Posts: 2130
Joined: Tue May 21, 2002 12:44 pm
Location: Saint Cloud (France)

Postby herrv » Fri Jan 30, 2004 7:34 am

Salut et merci a kephy pour la doc je l'imprime de suite
Zorro oui j'ai fait ca :( le prob C pas de sauvegarder l'etat du mfp avant de l'utiliser mais de l'initialiser apres un reset ... mais p'tetre que j'ai fait une connerie ailleur !
bon j'm'y r'met ce weekend ou plutot wiiiiiiiiiiiikeinde ! comme dit lorie !
:wink:
------------------------------------------------------
------------ /|\ l a p i n d e f /|\ -------------
* Pray The UnHoly Lapinou From Hell ! *
------------------------------------------------------
User avatar
herrv
Captain Atari
Captain Atari
 
Posts: 339
Joined: Thu May 29, 2003 10:19 am
Location: Rennes

Postby frost » Mon Feb 02, 2004 9:03 pm

Il faut sauvegarder un poil plus de registres pour cela. En fait il faut surtout sauvegarder le vector register et quelques autres très importants. Les timers, tu les coupent...

Je crois que tu trouveras ton bonheur dans ST Mag 69 ou 71 (les deux premiers que j'ai achetés !!!)
My blog, mostly about Atari and demo stuff.
User avatar
frost
Captain Atari
Captain Atari
 
Posts: 268
Joined: Sun Dec 01, 2002 2:50 am
Location: Pariiiiiis

Postby herrv » Tue Feb 03, 2004 9:21 pm

tu me les offres mon amour ???
comme C gentils !!! LOVE FROST !!!
------------------------------------------------------
------------ /|\ l a p i n d e f /|\ -------------
* Pray The UnHoly Lapinou From Hell ! *
------------------------------------------------------
User avatar
herrv
Captain Atari
Captain Atari
 
Posts: 339
Joined: Thu May 29, 2003 10:19 am
Location: Rennes

Postby frost » Wed Feb 04, 2004 8:35 pm

il est fou lui !!! lol


mais je veux bien tenter de les retrouver (faut voir s'ils sont chez moi ou chez mes parents) et te faire des photocopies. envois moi ton adresse postale en MP.
My blog, mostly about Atari and demo stuff.
User avatar
frost
Captain Atari
Captain Atari
 
Posts: 268
Joined: Sun Dec 01, 2002 2:50 am
Location: Pariiiiiis

Postby Shazz » Thu Feb 05, 2004 10:34 am

Eh Kellog's (mon roi) tu peux pas les scanner ? :)
...8bits are enough...
User avatar
Shazz
Atari Super Hero
Atari Super Hero
 
Posts: 548
Joined: Wed Aug 27, 2003 9:27 am
Location: Crétin des Alpes dauphinoises

Postby frost » Thu Feb 05, 2004 4:24 pm

Jeune courtisan impétueux, le royaume ne dispose pas du budget nécessaire à l'achat d'un scanner ! :roll:
My blog, mostly about Atari and demo stuff.
User avatar
frost
Captain Atari
Captain Atari
 
Posts: 268
Joined: Sun Dec 01, 2002 2:50 am
Location: Pariiiiiis

Postby Rajah Lone » Thu Feb 05, 2004 4:46 pm

Ca peut peut-être s'arranger... j'ai une petite collection de STMAG, et ma môman a eu un scanner pour son Noël à raccorder à son PC qui fait de l'internet.

Ce sont bien les numéros STMAG oldschool ci-dessus ?
User avatar
Rajah Lone
Captain Atari
Captain Atari
 
Posts: 192
Joined: Wed Aug 07, 2002 12:27 pm
Location: Lyon / France

Postby Rajah Lone » Sat Feb 07, 2004 2:37 pm

Bon, j'espère que c'est le bon article.
C'est dans le dossier http://rajah.atari.org/files/. fichiers jpg de 700 Ko à 500 Ko, nommés stmag69-xx.jpg.

Merci de prévenir (irc) quand vous les récupérer, c pour les effacer ensuite.
User avatar
Rajah Lone
Captain Atari
Captain Atari
 
Posts: 192
Joined: Wed Aug 07, 2002 12:27 pm
Location: Lyon / France

Postby herrv » Mon Feb 09, 2004 7:54 am

merci rajah !
j'ai telechargé les images :)
je ne C pas si ca cause bien du mfp apres reset mais dans tous les cas ca a l'air interessant :)
encore merci !
et a+
HerrV
------------------------------------------------------
------------ /|\ l a p i n d e f /|\ -------------
* Pray The UnHoly Lapinou From Hell ! *
------------------------------------------------------
User avatar
herrv
Captain Atari
Captain Atari
 
Posts: 339
Joined: Thu May 29, 2003 10:19 am
Location: Rennes

Postby herrv » Mon Feb 09, 2004 8:14 am

tiens j'ai transformé les images en pdf ...
ca poura tjrs servir :)
You do not have the required permissions to view the files attached to this post.
------------------------------------------------------
------------ /|\ l a p i n d e f /|\ -------------
* Pray The UnHoly Lapinou From Hell ! *
------------------------------------------------------
User avatar
herrv
Captain Atari
Captain Atari
 
Posts: 339
Joined: Thu May 29, 2003 10:19 am
Location: Rennes

Postby frost » Mon Feb 09, 2004 11:07 am

arg ! jsuis trop un nase !!! c'est pas ce numéro là !!!


mais maintenant j'ai récupéré mon falcon, je vais chercher le source sur mon skeudur !

(mais l'article en question parle de reset-demo et se trouve dans la série des stmag 69 à 75)
My blog, mostly about Atari and demo stuff.
User avatar
frost
Captain Atari
Captain Atari
 
Posts: 268
Joined: Sun Dec 01, 2002 2:50 am
Location: Pariiiiiis

Postby Zorro 2 » Mon Feb 09, 2004 11:13 am

frost wrote:arg ! jsuis trop un nase !!! c'est pas ce numéro là !!!
(mais l'article en question parle de reset-demo et se trouve dans la série des stmag 69 à 75)

Merci d'etre precis Frost, j'ai retrouve le code :
Code: Select all
*            LISTING No 1            *
*     Bloc gestionnaire de RESET     *
*                                    *
* Ce code est entierement relogeable *
*   Son utilisation necessite juste  *
*     un appel a la routine Init     *
* Voir le listing d'exemple fournit  *
*                                    *
*    ST Mag - Ric de NAOS - 1993     *

TrapVect   equ   $80

; Placez plutot la base video en fin
; de ram par defaut.
Video_base   equ   $78000

Init   move.l   #$31415926,$426.w
   lea   Reset(pc),a0
   move.l   a0,$42a.w
; Sauve le Vector Register du MFP
   lea   Mfp(pc),a0
   move.b   $fffffa17.w,(a0)
   rts

Reset   
* A > Initialisation hardware du ST
   move.w   #$2700,sr
; installation d'une pile
   lea   Pile(pc),sp
   
; Reinitialisation du MFP, mais
; coupe toutes ses interruptions
   lea   $fffffa01.w,a0
; Autorisations IERA-IERB
   move.b   #0,6(a0)   
   move.b   #0,8(a0)
; En cours ISRA-ISRB
   move.b   #0,14(a0)
   move.b   #0,16(a0)
; Masques IMRA-IMRB
   move.b   #0,18(a0)
   move.b   #0,20(a0)
; Restaure le Vector Register
   move.b   Mfp(pc),22(a0)
; Controles TACR-TBCR et TCDCR
   move.b   #0,24(a0)
   move.b   #0,26(a0)
   move.b   #0,28(a0)
; it. VBL par d‚faut
   lea   Rte(pc),a0
   move.l   a0,$70.w
   stop   #$2300
; Chip Video
; (valide l'adresse video)
   move.l   #Video_base,d0
   move.l   d0,$44e.w
   lsr.w   #8,d0
   move.b   d0,$ffff8203.w
   swap   d0
   move.b   d0,$ffff8201.w
; (frequence video = 50 Hz)
   move.b   #2,$ffff820a.w
; (basse resolution)
   move.w   #0,$ffff8260.w

; (efface la ram video)
   move.w   #7999,d7
   moveq   #0,d0
   move.l   #Video_base,a0
ClrVIDEO   move.l   d0,(a0)+
   dbf   d7,ClrVIDEO

; D‚s‚lection des drives
   move.b   #14,$ffff8800.w
   move.b   $ffff8800.w,d7
; bits 0 Â… 3 mis Â… 1
   ori.b   #$7,d7
   move.b   d7,$ffff8802.w

* B > Initialisation soft du programme

; Routine de relocation (cf STMag 74)   
   lea   Charge(pc),a0
   move.l   2(a0),d0
   add.l   6(a0),d0      
   move.l   d0,d1
   add.l   $e(a0),d0   
   
   lea   $1c(a0),a0      
   add.l   a0,d1
; adresse de fin du programme
; (debut de la zone BSS)
   lea   End(pc),a2
   move.l   d1,(a2)
   lea   0(a0,d0.l),a1   
; on ne d‚place pas le programme
   lea   LogAdr(pc),a2
   move.l   a0,(a2)

   add.l   (a1)+,a0
   move.l   LogAdr(pc),d1
   add.l   d1,(a0)
   moveq   #0,d0
   
BclReloc   move.b   (a1)+,d0
   tst.b   d0   
   beq.s   FinReloc
   cmp.b   #1,d0
   beq.s   IncrAdr
   add.w   d0,a0
   move.l   LogAdr(pc),d1
   add.l   d1,(a0)
   bra.s   BclReloc
IncrAdr   lea   $fe(a0),a0
   bra.s   BclReloc

; Effacement de sa section BSS   
FinReloc   lea   Charge(pc),a0
   move.l   $a(a0),d0
   move.l   End(pc),a1
ClrBSS   clr.b   (a1)+
   dbf   d0,ClrBSS

; Reprise de quelques exceptions
   lea   TrapVect.w,a0
   lea   Trp1(pc),a1
   lea   Rte(pc),a2
   move.l   a1,4(a0)
   move.l   a2,4*13(a0)
   move.l   a2,4*14(a0)

; d‚sactive le reset aprŠs le premier
; appel (pour permettre a l'utilisateur
; de rebooter apres la reset demo)
   clr.l   $426.w
   clr.l   $4d2.w
   
; Execution de l'ecran en reset demo
   move.l   LogAdr(pc),a0
   jmp   (a0)

Rte   rte

Trp1   tst.w   6(sp)
   bne.s   FinTrp1
   move.l   $0,sp
   move.l   $4,a0
   jmp   (a0)
FinTrp1   rte

Mfp   dc.l   0
LogAdr   dc.l   0
End   dc.l   0

; une pile de 256 mots longs   
   ds.l   $100   
Pile   ds.l   1

; Normalement, vous chargez ici votre prg
Charge   incbin   a:\music.prg
Member of NoExtra Team
User avatar
Zorro 2
Administrator
Administrator
 
Posts: 2130
Joined: Tue May 21, 2002 12:44 pm
Location: Saint Cloud (France)

Postby Zorro 2 » Mon Feb 09, 2004 11:16 am

Je fournis aussi l'exemple de l'installation de la reset demo :
Code: Select all
*         LISTING No 2          *
*                               *
*    Exemple d'installation     *
*       d'une reset d‚mo        *
*                               *
*  ST Mag - Ric de NAOS - 1993  *

   opt   x+

   clr.l   -(sp)
   move.w   #$20,-(sp)
   trap   #1
   addq.l   #6,sp
   move.l   d0,-(sp)
   
; initialisation pour que l'‚cran
; plac‚ en 'incbin' a la fin tourne
; en reset demo.
   jsr   ResetDemo
   
   move.l   $70.w,SaveVBL
   move.l   #MainRTE,$70.w

; ceci est mon programme en train
; de tourner...
; (on sort avec ESCAPE)

main   stop   #$2300
   cmp.b   #$1,$fffffc02.w
   bne.s   main

; d‚sactive le reset (au cas o—...)
   clr.l   $426.w
   clr.l   $4d2.w
   move.l   SaveVBL,$70.w

   move.w   #$20,-(sp)
   trap   #1
   addq.l   #6,sp

   clr.w   -(sp)
   trap   #1

SaveVBL   dc.l   0
MainRTE   rte
   
ResetDemo   incbin   a:\resetdmo.bin


Member of NoExtra Team
User avatar
Zorro 2
Administrator
Administrator
 
Posts: 2130
Joined: Tue May 21, 2002 12:44 pm
Location: Saint Cloud (France)

Postby frost » Mon Feb 09, 2004 1:05 pm

Yeeees ! je l'avais dit !!! il faut sauvegarder le vector register du mfp !!! :D

merci Zorro !
My blog, mostly about Atari and demo stuff.
User avatar
frost
Captain Atari
Captain Atari
 
Posts: 268
Joined: Sun Dec 01, 2002 2:50 am
Location: Pariiiiiis

Postby herrv » Mon Feb 09, 2004 4:21 pm

merci les copains ! :)
------------------------------------------------------
------------ /|\ l a p i n d e f /|\ -------------
* Pray The UnHoly Lapinou From Hell ! *
------------------------------------------------------
User avatar
herrv
Captain Atari
Captain Atari
 
Posts: 339
Joined: Thu May 29, 2003 10:19 am
Location: Rennes


Return to MJJ-Prod [FR]

Who is online

Users browsing this forum: CommonCrawl [Bot] and 0 guests